33eff7c7d8
Rename src/jolt -> stdlib (the runtime-loaded layer; jolt-core stays the seed-baked layer) and update the loader / emit-image / doc paths. Drop dead code: the spike/ experiments, the duplicate clojuredocs-export.edn (json moves to tools/), the Janet-era jolt.http binding, and the orphaned persistent_vector.clj whose ns/path didn't even match. Strip porting residue from comments and docstrings across host/chez, jolt-core, stdlib, tests, and docs: internal issue ids, "Phase N" markers, and the "vs Janet" historical exposition, leaving present-tense descriptions and the real JVM-Clojure semantic contrasts. Same pass over the corpus suite labels. The seed is unchanged (docstrings/comments aren't emitted), so the self-host fixpoint and corpus are untouched. Port tools/spec_coverage.py off the dead janet probe to bin/joltc and regenerate coverage.md; drop the dead :host/janet rule from certify.clj and regenerate the conformance profile. Add docs/host-interop.md (the JVM shims and how to register your own host class from a library) and a writing-style note in CLAUDE.md. Stabilize the four racy concurrency corpus cases (future-cancel and agent send/send-off): give the future a sleeping body and the agent a slow action, so cancel reliably catches an in-flight future and deref reliably reads the pre-update snapshot. They certify deterministically now, so drop their :flaky allowlist entries and the orphaned legend.
33 lines
1.3 KiB
Clojure
33 lines
1.3 KiB
Clojure
;; Verbatim from clojure.template (Stuart Sierra) — pure Clojure over
|
|
;; clojure.walk, which jolt ships. Added so honeysql's :clj branch (which
|
|
;; requires clojure.template) loads under JOLT_FEATURES including clj.
|
|
(ns clojure.template
|
|
"Macros that expand to repeated copies of a template expression."
|
|
(:require [clojure.walk :as walk]))
|
|
|
|
(defn apply-template
|
|
"For use in macros. argv is an argument list, as in defn. expr is
|
|
a quoted expression using the symbols in argv. values is a sequence
|
|
of values to be used for the arguments.
|
|
|
|
apply-template will recursively replace argument symbols in expr
|
|
with their corresponding values, returning a modified expr.
|
|
|
|
Example: (apply-template '[x] '(+ x x) '[2])
|
|
;=> (+ 2 2)"
|
|
[argv expr values]
|
|
(assert (vector? argv))
|
|
(assert (every? symbol? argv))
|
|
(walk/postwalk-replace (zipmap argv values) expr))
|
|
|
|
(defmacro do-template
|
|
"Repeatedly copies expr (in a do block) for each group of arguments
|
|
in values. values are automatically partitioned by the number of
|
|
arguments in argv, an argument vector as in defn.
|
|
|
|
Example: (macroexpand '(do-template [x y] (+ y x) 2 4 3 5))
|
|
;=> (do (+ 4 2) (+ 5 3))"
|
|
[argv expr & values]
|
|
(let [c (count argv)]
|
|
`(do ~@(map (fn [a] (apply-template argv expr a))
|
|
(partition c values)))))
|